# Clean, simple, compatible and meaningful.
# Tested on Linux, Unix and Windows under ANSI colors.
# It is recommended to use with a dark background.
# Colors: black, red, green, yellow, *blue, magenta, cyan, and white.
#
# Mar 2013 Yad Smood

# VCS
YS_VCS_PROMPT_PREFIX1=" %{$reset_color%}on%{$fg[blue]%} "
YS_VCS_PROMPT_PREFIX2=":%{$fg[cyan]%}"
YS_VCS_PROMPT_SUFFIX="%{$reset_color%}"
YS_VCS_PROMPT_DIRTY=" %{$fg[red]%}x"
YS_VCS_PROMPT_CLEAN=" %{$fg[green]%}o"

# Git info
local git_info='$(git_prompt_info)'
ZSH_THEME_GIT_PROMPT_PREFIX="${YS_VCS_PROMPT_PREFIX1}git${YS_VCS_PROMPT_PREFIX2}"
ZSH_THEME_GIT_PROMPT_SUFFIX="$YS_VCS_PROMPT_SUFFIX"
ZSH_THEME_GIT_PROMPT_DIRTY="$YS_VCS_PROMPT_DIRTY"
ZSH_THEME_GIT_PROMPT_CLEAN="$YS_VCS_PROMPT_CLEAN"

# HG info
local hg_info='$(ys_hg_prompt_info)'
ys_hg_prompt_info() {
        # make sure this is a hg dir
        if [ -d '.hg' ]; then
                echo -n "${YS_VCS_PROMPT_PREFIX1}hg${YS_VCS_PROMPT_PREFIX2}"
                echo -n $(hg branch 2>/dev/null)
                if [[ "$(hg config oh-my-zsh.hide-dirty 2>/dev/null)" != "1" ]]; then
                        if [ -n "$(hg status 2>/dev/null)" ]; then
                                echo -n "$YS_VCS_PROMPT_DIRTY"
                        else
                                echo -n "$YS_VCS_PROMPT_CLEAN"
                        fi
                fi
                echo -n "$YS_VCS_PROMPT_SUFFIX"
        fi
}

local exit_code="%(?,,C:%{$fg[red]%}%?%{$reset_color%})"

# Conda
local conda_info='$(conda_prompt_info)'
YS_THEME_CONDA_PROMPT_PREFIX=" %{$fg[yellow]%}"
YS_THEME_CONDA_PROMPT_SUFFIX=" %{$reset_color%}%"
conda_prompt_info() {
        CONDA_DEFAULT_ENV_NAME=""
        if [ -n "$CONDA_DEFAULT_ENV" ]; then
            CONDA_DEFAULT_ENV_NAME="($CONDA_DEFAULT_ENV)"
        fi
        echo -n "${YS_THEME_CONDA_PROMPT_PREFIX}${CONDA_DEFAULT_ENV_NAME:t}${YS_THEME_CONDA_PROMPT_SUFFIX}"
}

# Prompt format:
#
# PRIVILEGES USER @ MACHINE in DIRECTORY on git:BRANCH STATE [TIME] C:LAST_EXIT_CODE
# $ COMMAND
#
# For example:
#
# % ys @ ys-mbp in ~/.oh-my-zsh on git:master x [21:47:42] C:0
# $

# PROMPT="
# %{$terminfo[bold]$fg[blue]%}#%{$reset_color%} \
# %(#,%{$bg[yellow]%}%{$fg[black]%}%n%{$reset_color%},%{$fg[cyan]%}%n) \
# %{$reset_color%}@ \
# %{$fg[green]%}%m \
# %{$reset_color%}in \
# %{$terminfo[bold]$fg[yellow]%}%~%{$reset_color%}\
# ${hg_info}\
# ${git_info}\
# ${svn_info}\
# ${venv_info}\
#  \
# [%*] $exit_code
# %{$terminfo[bold]$fg[red]%}$ %{$reset_color%}"

PROMPT="
%{$terminfo[bold]$fg[blue]%}#%{$reset_color%} \
%(#,%{$fg[cyan]%}%m,%{$fg[green]%}%m) \
%{$reset_color%}in \
%{$terminfo[bold]$fg[yellow]%}%~%{$reset_color%}\
${hg_info}\
${git_info}\
 \
[%*]\
${conda_info}\
 \
$exit_code
%{$terminfo[bold]$fg[red]%}$ %{$reset_color%}"
